***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Jan 30, 2026                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt P6SMB56A-AU  A K 
.param
+vc0 = 2.746e-10	vc1 = 4.016e-11		vc2 = 9.000e-1		vc3 = 2.613e-11		vc4 = 7.005e-2
+tc1 = 3.698e-2		tc2 = 3.355e-2		tc3 = 6.373e-2		tc4 = 3.207e-2
d1  A A1 zener
g1 A1 A value = {irexp(v(A1,A))}
v1 A1 K1 0
e1 K1 K value = {rbv(i(v1))}
.func irexp(v) {(vc0+vc1*v**vc2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc3*exp(vc4*v))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
.func rbv(i) {1.742*min(i,0)}
.model zener d
***** flag parameter *****
+level = 1 
***** dc model parameter *****
+ is = 1.318e-12	  n = 1.190		 rs = 3.607e-2
+ibv = 1.000e-3	        nbv = 1.000	         bv = 56
+ikf = 1.500e-1
***** capacitance parameter *****
+cjo = 4.4403e-10	  m = 3.361e-1		 vj = 5.762e-1 
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		 eg = 1.132	        xti = 3
+trs1 = 3.206e-3       tikf = 3.106e-3
+tbv1 = 1.049e-3       tbv2 = -1.282e-6    
.ends P6SMB56A-AU
*$
